#!/usr/bin/perl
##################################################
# Takes a list of firefox bookmarks (HTML format)
# and adds them to my del.icio.us account.
# Usage:
#   perl deladd.pl <bookmark-file>

# It will prompt you for del.icio.us username
# and password.
# 
# Programmer:
#   J. van Donsel
#   12/29/2004
#
##################################################
use strict;
use warnings;

#########################################
# sub convert_to_html_string
# Replaces non-ascii characters with %xx
#########################################
sub convert_to_html_string($)
{
    my @sdesc = split "", $_[0];
    map { $_=sprintf("%%%02X", ord($_)) if ($_!~/[\w.\/:]/)} @sdesc;
    my $desc = join "", @sdesc;
    return $desc;
} # end convert_to_html_string

#########################################
# main
#
#########################################
if (scalar(@ARGV) == 0)
{
    print "Usage:\n\tperl deladd.pl <bookmark-file>\n";
    die;
}

# Get username/password
print "Enter del.icio.us username:";
my $USERNAME=<STDIN>;
chomp $USERNAME;

print "Enter del.icio.us password:";
system("stty -echo");
my $PASSWORD=<STDIN>;
system("stty echo");
chomp $PASSWORD;

# Create a user agent object
use LWP::UserAgent;
my $ua = LWP::UserAgent->new;
$ua->agent("Delicious Bookmark Adder");

# Get my entire list of bookmarks
my $req = HTTP::Request->new(GET => "http://del.icio.us/api/posts/all");
$req->content_type('application/x-www-form-urlencoded');
$req->content('query=libwww-perl&mode=dist');
$req->authorization_basic($USERNAME, $PASSWORD);
my $res = $ua->request($req);
my $all_posts;

# Check the outcome of the response
if ($res->is_success) 
{
    # Save our current post list as one long block
    $all_posts = $res->content;
}
else 
{
    print $res->status_line, "\n";
    die;
}

# Go through each line of the bookmark file
while(<>)
{
    # Look for the URL (begins with HTTP) and the description tags
    if (/A HREF="(http:\/\/[^"]+)"[^>]*>([^<]+)</)
    {
        my $url = $1;
        my $desc = $2;

        print "\n";
        print "Got url of: $url\n";
        print "Got description of: $desc\n";

        # Skip certain URL's. Probably private stuff.
        if (
            $url =~ /\&/ ||
            $url =~ /\?/ ||
            $url =~ /nmss/i ||
            $url =~ /webmail/i ||
            $url =~ /fibroid/i ||  
            $url =~ /192.168/i ||  
            $url =~ /\/admin\//i
            )
        {
            print "SKIPPING\n";
            next;
        }

        # Check this url against our current list of posted bookmarks
        if ($all_posts =~ /\Q$url\E/)
        {
            print ("FOUND ALREADY\n");
            next;
        }
        else
        {
            print ("NEW\n");
        }

        # webify the strings
        $url = convert_to_html_string($url);
        $desc = convert_to_html_string($desc);

        # Create a request
        $req = HTTP::Request->new(GET => "http://del.icio.us/api/posts/add?&url=$url&description=$desc");
        $req->content_type('application/x-www-form-urlencoded');
        $req->content('query=libwww-perl&mode=dist');
        $req->authorization_basic($USERNAME, $PASSWORD);

        # Pass request to the user agent and get a response back
        my $res = $ua->request($req);

        # Check the outcome of the response
        if ($res->is_success) 
        {
            print "ADDED\n";
        }
        else 
        {
            # Error
            print $res->status_line, "\n";
        }

        # API for del.icio.us asks that queries be kept slow.
        sleep 3;
    }
} #end while